Forum Domoticz en français

Code : Tout sélectionner

/*  Sonnette sans fil pour DOMOTICZ
    Dernière mise à jour le 09/08/2020

    A utiliser avec un Arduino ou un ATtiny85
*/

#include <NewRemoteTransmitter.h>

// Inititalisation matérielle

int bouton = 2;               // Port 2 (broche 7 de l'ATtiny85 ou broche 5 sur un Arduino nano) sur lequel est raccordé le BP (avec un pull-down de 22K (rouge-rouge-orange))
int pinTx = 3;                // Port 3 (broche 2 de l'ATtiny85 ou broche 6 sur un Arduino nano) sur lequel est raccordé l'emetteur type FS1000A
int led = 4;                  // Port 4 (broche 3 de l'ATtiny85 ou broche 7 sur un Arduino nano) sur lequel est raccordée une led sur la sonnette (optionnelle, s'allume 0,5 secondes quand l'emetteur envoi un signal)

// Initialisation logicielle

int adresse = 2;              // Adresse de la sonnette, mettre 3 par exemple pour utiliser le même montage ailleurs dans la maison pour un contact de porte, boite à lettre, ...
int periode = 260;            
int nbRepetitionCode = 1;     
boolean etatBouton = 0;       

NewRemoteTransmitter transmitter(adresse, pinTx, periode, nbRepetitionCode);

void setup()
{
  pinMode(bouton, INPUT);
  pinMode(led, OUTPUT);
}

void loop()
{
  etatBouton = digitalRead(bouton);               // Surveillance d'un appui sur le BP
  if (etatBouton==1)                              // Détection de l'appui
    {
    transmitter.sendUnit(1, true);                // Envoi du signal ON pour Domoticz (door bell ou virtual switch ...)
    
    digitalWrite(led, HIGH);                      // Allumage et extinction de la led témoin d'envoi du signal
    delay(500);
    digitalWrite(led, LOW);
    
    transmitter.sendUnit(1, false);                // Envoi du signal OFF pour Domoticz
    }
}

Code : Tout sélectionner

//NOTE: The ATtiny85 must be set to use the default 1-MHz internal clock

// ATtiny85 RF Transmitter
// Transmits commands to an Etekcity RF outlet
// Must know the specific codes being transmitted
// 0 bit: 188us
// 1 bit: 3x zero bit length
// Sync (start) time: 30x zero bit
// Message length: 24 data bits, 1 stop bit
// Written by Boomer48: September 2019

#include <avr/sleep.h>

#define Serial_RF 0
#define Button1 1
#define Button2 2
#define Button3 3
#define Button4 4
#define DelayShort 188
#define DelayLong 564
#define DelaySync 5640
#define num_msgs 5 // number of messages to transmit

byte temp;

void setup ()
{
  pinMode(Serial_RF, OUTPUT);
  digitalWrite(Serial_RF, 0);
  digitalWrite (Button1, HIGH);  // enable pull-up
  digitalWrite (Button2, HIGH);  // enable pull-up
  digitalWrite (Button3, HIGH);  // enable pull-up
  digitalWrite (Button4, HIGH);  // enable pull-up

  // Set interrupt-on-change registers for buttons
  bitClear(GIMSK, INT0); // disable INT0 external interrupt
  bitSet(GIMSK, PCIE); // enable interrupt-on-change
  bitSet(PCMSK, Button1);
  bitSet(PCMSK, Button2);
  bitSet(PCMSK, Button3);
  bitSet(PCMSK, Button4);

  bitClear(ADCSRA, ADEN); // disable ADC for low power mode
  set_sleep_mode (SLEEP_MODE_PWR_DOWN);

}  // end of setup

void loop ()
{
  sleep_enable();

  // Do not interrupt before we go to sleep, or the
  // ISR will detach interrupts and we won't wake.
  noInterrupts();

  // We are guaranteed that the sleep_cpu call will be done
  // as the processor executes the next instruction after
  // interrupts are turned on.
  interrupts();  // one cycle
  sleep_cpu();   // one cycle
} // end of loop

void Transmit1 ()
{
  temp = num_msgs;

  while (temp > 0) {
    Write_RF(0x44);
    Write_RF(0x15);
    Write_RF(0x33); // turn on outlet 1
    Stop_Bit();
    delayMicroseconds(DelaySync);
    temp--;
  }
}

void Transmit2 ()
{
  temp = num_msgs;

  while (temp > 0) {
    Write_RF(0x44);
    Write_RF(0x15);
    Write_RF(0x3C); // turn off outlet 1
    Stop_Bit();
    delayMicroseconds(DelaySync);
    temp--;
  }
}

void Transmit3 ()
{
  temp = num_msgs;

  while (temp > 0) {
    Write_RF(0x44);
    Write_RF(0x15);
    Write_RF(0xC3); // turn on outlet 2
    Stop_Bit();
    delayMicroseconds(DelaySync);
    temp--;
  }
}

void Transmit4 ()
{
  temp = num_msgs;

  while (temp > 0) {
    Write_RF(0x44);
    Write_RF(0x15);
    Write_RF(0xCC); // turn off outlet 2
    Stop_Bit();
    delayMicroseconds(DelaySync);
    temp--;
  }
}

void Write_RF (byte Data_Byte)
{
  byte i = 8; // send MSB first

  while (i > 0)
  {
    i--;
    digitalWrite(Serial_RF, 1);

    if (bitRead(Data_Byte, i) == 0)
    {
      delayMicroseconds(DelayShort);
      digitalWrite(Serial_RF, 0);
      delayMicroseconds(DelayLong);
    }
    else
    {
      delayMicroseconds(DelayLong);
      digitalWrite(Serial_RF, 0);
      delayMicroseconds(DelayShort);
    }
  }
}

void Stop_Bit ()
{
  digitalWrite(Serial_RF, 1);
  delayMicroseconds(DelayShort);
  digitalWrite(Serial_RF, 0);
  delayMicroseconds(DelayLong);
}

// Interrupt-on-change handler
ISR (PCINT0_vect)
{
  delayMicroseconds(16000); // debounce switch
  delayMicroseconds(16000); // debounce switch
  delayMicroseconds(16000); // debounce switch

  if (digitalRead(Button1) == LOW)
    Transmit1();
  else if (digitalRead(Button2) == LOW)
    Transmit2();
  else if (digitalRead(Button3) == LOW)
    Transmit3();
  else if (digitalRead(Button4) == LOW)
    Transmit4();
}

Code : Tout sélectionner

digitalWrite (Button1, HIGH);  // enable pull-up

Code : Tout sélectionner

pinMode(Button1, INPUT_PULLUP);